A very simple configuration that globally maps CapsLock to Escape and Ctrl+U to Page Up can look like this:

# flake.nix
{
  inputs.xremap-flake.url = "github:xremap/nix-flake";
  outputs = inputs@{ nixpkgs, ... }: {
    nixosConfigurations.nixos = nixpkgs.lib.nixosSystem {
      system = "x86_64-linux";
      modules = [
        inputs.xremap-flake.nixosModules.default
        /* This is effectively an inline module */
        {
          users.users.root.password = "hunter2";
          system.stateVersion = "24.05";

          services.xremap.enable = true;

          # Modmap for single key rebinds
          services.xremap.config.modmap = [
            {
              name = "Global";
              remap = { "CapsLock" = "Esc"; }; # globally remap CapsLock to Esc
            }
          ];

          # Keymap for key combo rebinds
          services.xremap.config.keymap = [
            {
              name = "Example ctrl-u > pageup rebind";
              remap = { "C-u" = "PAGEUP"; };
              # NOTE: no application-specific remaps work without features (see configuration)
            }
          ];
        }
      ];
    };
  };
}

# flake.nix
{
  inputs.xremap-flake.url = "github:xremap/nix-flake";
  outputs = inputs@{ nixpkgs, ... }: {
    nixosConfigurations.nixos = nixpkgs.lib.nixosSystem {
      system = "x86_64-linux";
      modules = [
        inputs.xremap-flake.nixosModules.default
        /* This is effectively an inline module */
        {
          users.users.root.password = "hunter2";
          users.users.alice = {
            password = "hunter2";
            isNormalUser = true;
          };

          system.stateVersion = "24.05";
          # This configures the service to only run for a specific user
          services.xremap = {
            enable = true;
            /* NOTE: since this sample configuration does not have any DE, xremap needs to be started manually by systemctl --user start xremap */
            serviceMode = "user";
            userName = "alice";
          };
          # Modmap for single key rebinds
          services.xremap.config.modmap = [
            {
              name = "Global";
              remap = { "CapsLock" = "Esc"; }; # globally remap CapsLock to Esc
            }
          ];

          # Keymap for key combo rebinds
          services.xremap.config.keymap = [
            {
              name = "Example ctrl-u > pageup rebind";
              remap = { "C-u" = "PAGEUP"; };
            }
          ];
        }
      ];
    };
  };
}

# flake.nix
{
  inputs.xremap-flake.url = "github:xremap/nix-flake";
  outputs = inputs@{ nixpkgs, ... }: {
    nixosConfigurations.nixos = nixpkgs.lib.nixosSystem {
      system = "x86_64-linux";
      modules = [
        inputs.xremap-flake.nixosModules.default
        /* This is effectively an inline module */
        (
          { pkgs, ... }:
          {
            users.users.root.password = "hunter2";
            users.users.alice = {
              password = "hunter2";
              isNormalUser = true;
              extraGroups = [ "wheel" ];
            };

            system.stateVersion = "24.05";

            services.xserver = {
              enable = true;
              desktopManager.xfce.enable = true; # xfce is just an example
            };
            environment.systemPackages = [ pkgs.kitty ];

            /* Run a single one-shot service that allows root's services to access user's X session */
            systemd.user.services.set-xhost = {
              description = "Run a one-shot command upon user login";
              path = [ pkgs.xorg.xhost ];
              wantedBy = [ "default.target" ];
              script = "xhost +SI:localuser:root";
              environment.DISPLAY = ":0.0"; # NOTE: This is hardcoded for this flake
            };

            /* Enable X11 feature support */
            services.xremap.withX11 = true;
            services.xremap.enable = true;
            # Modmap for single key rebinds
            services.xremap.config.modmap = [
              {
                name = "Global";
                remap = { "CapsLock" = "Esc"; }; # globally remap CapsLock to Esc
              }
            ];

            # Keymap for key combo rebinds
            services.xremap.config.keymap = [
              {
                name = "Example ctrl-u > pageup rebind, only for specific application";
                remap = { "C-u" = "PAGEUP"; };
                application.only = [ "kitty" ];
              }
            ];
          }
        )
      ];
    };
  };
}

{
  description = "Home-manager flake for xremap";

  inputs = {
    nixpkgs.url = "nixpkgs/nixos-24.11";

    home-manager.url = "github:nix-community/home-manager/release-24.11";
    home-manager.inputs.nixpkgs.follows = "nixpkgs";

    xremap-flake.url = "github:xremap/nix-flake";
  };

  outputs = inputs@{ self, nixpkgs, home-manager, ... }:
    let
      lib = nixpkgs.lib;
      system = "x86_64-linux";
      pkgs = nixpkgs.legacyPackages.${system};
    in {
      ...
      homeConfigurations = {
        user = home-manager.lib.homeManagerConfiguration {
          inherit pkgs;
          modules = [
            inputs.xremap-flake.homeManagerModules.default
            {
              services.xremap = {
                enable = true;
                # Modmap for single key rebinds
                config.modmap = [{
                  name = "Global";
                  remap = { "CapsLock" = "Esc"; };
                }];

                # Keymap for key combo rebinds
                config.keymap = [{
                  name = "Example ctrl-u > pageup rebind";
                  remap = { "C-u" = "PAGEUP"; };
                }];
              };
            }
          ];
        };
      };
    };
}